こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

Excelでひとつ置き(A1、A3、A5・・・)に合計とかふたつ置き(A1、A4、A7・・・)に合計というのは可能なのでしょうか?

タイトルの通りなのですが、
エクセルの雛形の関係上例えば
A1に「あ」という商品の代金 A2にその消費税
A3に「い」という商品の代金 A4にその消費税…
などという入力をすることがあり、
最後に商品代金だけ、消費税だけを計算したいとき
今まではA1+A3+A5+・・・という風に手でいちいち計算していたのですが
何か利用できそうな関数・数式はないものかと思い質問しました。

同じように2つ置き(A1+A4+A7+・・・)の方法もありませんでしょうか?

投稿日時 - 2008-07-16 14:00:08

QNo.4180878

すぐに回答ほしいです

質問者が選んだベストアンサー

一例です。
A1:A10範囲とします。
■奇数行の計数
=SUMPRODUCT((MOD(ROW(A1:A10),2)=1)*A1:A10)
■奇数行の計数
=SUMPRODUCT((MOD(ROW(A1:A10),2)=0)*A1:A10)

■3行毎の計数
=SUMPRODUCT((MOD(ROW(A1:A10),3)=1)*A1:A10)

投稿日時 - 2008-07-16 14:12:43

お礼

ご回答ありがとうございます。
奇数行・偶数行の計算、参考になりました。

投稿日時 - 2008-07-18 09:49:32

ANo.2

このQ&Aは役に立ちましたか?

12人が「このQ&Aが役に立った」と投票しています

回答(5)

ANo.5

1,3,5・・
は=MOD(ROW()-2,2)=0 でTRUEになる行です(第2行目から開始としてます)
1,4,7・・

=MOD(ROW()-2,3)=0 でTRUEになる行です(第2行目から開始としてます)
ーー
ですから
B列        C列(参考)C列(参考)
1TRUETRUE
2FALSEFALSE
3TRUEFALSE
4FALSETRUE
5TRUEFALSE
6FALSEFALSE
7TRUETRUE
8FALSEFALSE
9TRUEFALSE

ーーーー2512
前者は =SUM(IF(MOD(ROW(B2:B10)-2,2)=0,B2:B10,0))
と入れてSHIFT+CTRL+ENTERを同時押しする。配列数式。
結果 25
後は =SUM(IF(MOD(ROW(B2:B10)-2,3)=0,B2:B10,0))
と入れてSHIFT+CTRL+ENTERを同時押しする。
結果 12
こういう式もあるということ。

投稿日時 - 2008-07-16 14:54:03

お礼

ご回答ありがとうございました。
参考になりました。

今回は色んな方法のご回答を頂き、皆様ありがとうございました。
実際に使わせていただいた方法と、
今後個人的に使えそうな方法をご提案頂いた方に
ポイントをつけさせていただきます。ありがとうございました。

投稿日時 - 2008-07-18 09:52:47

ANo.4

これも一例です。

A1に商品代金 B1に「あ」という商品の代金
A2に消費税  B2に「あ」という商品の消費税

A3に商品代金 B3に「い」という商品の代金
A4に消費税  B4に「い」という商品の消費税・・・

Bの101に
=SUMIF($A$1:$A$100,"商品代金",B$1:B$100)
としますと、B列の商品代金だけをプラスします。
=SUMIF($A$1:$A$100,"消費税",B$1:B$100)
としますと、B列の消費税だけ計算します。

2つおきにしたい時もこの
応用でできませんでしょうか?

投稿日時 - 2008-07-16 14:40:22

お礼

ご回答ありがとうございました。
参考になりました。

投稿日時 - 2008-07-18 09:51:29

ANo.3

すでにありますが別の方法も。
たとえばA列にタイトル、B列にデータとして
A     B
代金   1000
消費税    50
代金   2000
消費税   100
として、B4に代金の合計(A1とA3の計)、B5に消費税の合計(A2とA4の計)を出すなら、B4には=SUMIF($A$1:$B$4,"代金",$B$1:$B$4)とし、B5には=SUMIF($A$1:$B$4,"消費税",$B$1:$B$4)と入れるとできます。
この関数は左の「代金」とか「消費税」をキーにそれがある行の数値を合計する意味ですのできっちり1行おきでなくてもできますし、ワイルドカード(*です)を使えば応用も利きます。たとえば、=SUMIF($A$1:$B$4,"消費税",$B$1:$B$4)を=SUMIF($A$1:$B$4,"*税",$B$1:$B$4)とすると消費税も所得税も住民税も、最後に税が付いていれば集計します。
こんなやり方もありますよ。
参考までに。

投稿日時 - 2008-07-16 14:39:27

お礼

ご回答ありがとうございます。
あ~、こういうやり方もあるのですね。
すでに雛型があるので、今回は使えませんが
今後非常に参考になりそうなやり方です。ありがとうございました。

投稿日時 - 2008-07-18 09:50:53

ANo.1

過去ログです。
http://okwave.jp/qa2194665.html
ご参考になるかと。

投稿日時 - 2008-07-16 14:06:47

お礼

ありがとうございます。
似たような質問があったのですね。参考になりました。

投稿日時 - 2008-07-18 09:48:15

あなたにオススメの質問